;**************************************************************************
;    C_REMOTO_ON/OFF_TRIAC.ASM
;
;    MODO DISPARO CONTINUO (CADA 512 US), SEM USAR SENSOR DE PASSAGEM POR ZERO
;    RECEPTOR RF PARA CONTROLE REMOTOS (CHAVEIRINHOS) C/ CI HT6P20B
; 
;    PARA DECODIFICAR UTILIZA UM PIC 12F675 (OPCIONALMENTE UM 12F629, DES-
;    COMENTANDO/COMENTANDO  AS LINHAS CITADAS NO TEXTO).
;
;    CLAUDIO LÁRIOS        INICIO: 04-10-2013  TERMINO:05-10-2013

;    OBJETIVO: CONTROLAR CARGAS COMO LAMPADAS, (INCLUSIVE FLUORESCENTE MINIA
;    TURA ELETRÔNICA), VENTILADORES, RESISTENCIAS,ETC, EM MODO ON/OFF APENAS,
;    COM TRIAC TIC246 E MICROCONTROLADOR PIC 12F675.
;    CONTROLES REMOTOS DEVEM SER 'APRENDIDOS'  ANTES DO USO.
;    ULTIMO AJUSTE FICARÁ GRAVADO, E EM CASO DE RESET,OU FALTA DE ENERGIA,
;    SERÁ RECARREGADO AUTOMÁTICAMENTE ESTE VALOR.
;    USO:1 BOTÃO DO CONTROLE REMOTO LIGA  E O OUTRO DESLIGA.
 
;   
;    ANTES DE COMPILAR, ESCOLHAS SUAS DEFINIÇÕES ABAIXO (DEFINIÇÕES DE USUARIO)
;    O MODO DE APRENDIZADO FOI REFORMULADO: APENAS APRENDA UM BOTÃO, QUE OS 
;    OUTROS  JÁ SERÃO ACEITOS.
;**************************************************************************
;
;   GRAVAR CONTROLE:  APERTE QUALQUER BOTÃO DO CONTROLE E MANTENHA APERTADO.
;   APERTE TAMBÉM O BOTÃO 'LEARN' NA PLACA (PINO 6 DO PIC 12F675  A MASSA)E 
;   SOLTE-O EM MENOS DE 1 SEGUNDOS.  O LED 'LEARN'(PINO 7)   PISCARÁ 1
;   VEZ, PARA INDICAR 'CODE APRENDIDO'. OS OUTROS BOTÕES JÁ SERÃO APRENDIDOS.
;   APAGAR TODOS OS CONTROLES DA MEMÓRIA:  APERTAR BOTÃO 'LEARN' NA PLACA E 
;   MANTENHA PRESSIONADO POR MAIS DE 10 SEGUNDOS.    O LED 'LEARN' (PINO 7) 
;   PISCARÁ 3 VEZES , INDICANDO O PLENO APAGAMENTO DE TODOS OS SENSORES DA 
;   MEMÓRIA. APÓS ISTO, CADA CONTROLE DEVERÁ SER 'REAPRENDIDO' NOVAMENTE PARA
;   OPERAR.

;   OBS. ESTE CIRCUITO TRABALHA COM ALTAS TENSÕES. TODOS OS CUIDADOS DE SEGU-
;   RANÇA DEVEM SER TOMADOS. NÃO INDICADO PARA INICIANTES.
;   O CHIP DEVE SER GRAVADO EXTERNAMENTE AO CIRCUITO E DEPOIS COLOCADO. 
;   NÃO TENTE GRAVAR 'IN-CIRCUIT' SOB RISCO DE DANIFICAR SEUS EQUIPAMENTOS 
;   (PC) E RISCO DE ELETROCUÇÃO. 
;   O MONTADOR CORRERÁ OS RISCOS POR CONTA PRÓPRIA. 
;   ESTE DISPOSITIVO É APENAS DIDÁTICO, MONTADO APENAS EM PROTOBOARD, SUJEITO
;   A BUGS AINDA NÃO IDENTIFICADOS. 
;*************************************************************************** 
;   CERTIFIQUE-SE DE TER O  BYTE DE CALIBRAÇÃO NO ENDEREÇO 0X3FF SALVO
;===================================================================================================================
;DEFINIÇÕES DO USUARIO (DESCOMENTE A OPÇÃO DESEJADA E COMENTE AS OUTRAS)

;#DEFINE PIC_629     ;ESCOLHE MICROCONTROLADOR PIC12F629
#DEFINE PIC_675    ;ESCOLHE MICROCONTROLADOR PIC12F675

;====================================================================================================================
    IFDEF PIC_675
	LIST P=12f675 , R=DEC
 	INCLUDE "P12F675.INC"
    ENDIF
    IFDEF PIC_629
 	LIST P=12f629 , R=DEC
 	INCLUDE "P12F629.INC"
    ENDIF
;PALAVRA DE CONFIGURAÇÃO
	ERRORLEVEL      -302   
	__CONFIG		_CP_OFF & _PWRTE_ON & _WDT_OFF & _INTRC_OSC_NOCLKOUT & _BODEN_ON & _MCLRE_ON

;DEFINIÇÕES
#DEFINE		BANK0	BCF	STATUS,RP0 	 ;SETA BANK0 DE MEMORIA
#DEFINE		BANK1	BSF	STATUS,RP0	 ;SETA BANK1
#DEFINE		FLAG	FLAGS,0          ;FLAG DE SITUAÇÃO
#DEFINE		FLAG1	FLAGS,1     	 ;FLAG DE NOVA LEITURA
#DEFINE		FLAG_R	FLAGS,2     	 ;FLAG DE 'LEARN' APRENDER
#DEFINE		FLAGGR	FLAGS,3     	 ;FLAG DE 'LEARN' APRENDER
#DEFINE		FLAG_JAON	FLAGS,4    	 ;FLAG DE 'JAON'
#DEFINE		FLAG_JAOFF	FLAGS,5      ;FLAG DE 'JAOFF'

;DEFINIÇÕES DE PORTAS DE SAIDA
#DEFINE LED		    GPIO,0  			;PINO 7  SAIDA LED 'LEARN'
#DEFINE SIN      	GPIO,2				;PINO 5- IN RF
#DEFINE LRN      	GPIO,1				;PINO 6- ENTRADA DO BOTÃO LEARN
#DEFINE GATE      	GPIO,4				;PINO 3- SAIDA DO TRIAC
#DEFINE TRISGATE    TRISIO,4			;PINO 3- SAIDA DO TRIAC
;RAM
     CBLOCK  0X20
 RES3,RES2,RES1,RES0,AUX,C3,C2,C1,C0,WS,TEMP,BITCOUNTER,FLAGS,TL0,TL1,TL2,Z2,Z1,Y1,Y0
  LcdDelayCounter,LcdDelayCounter1,tmpLcdRegister,tmpLcdRegister1,SITUAÇÃO
  temp,SDATA,AUX2 ,LC,HC ,CONT,RES3A,RES2A,RES1A,RES0A,X,R0,R1,R2,R3,TMP1,TMP2,TMP3,ADDRESS,TMP
  STATUSTEMP,WTEMP
     ENDC
;EQUATES
TMAX    EQU  .50       ;TEMPO MAXIMO DO SINAL LOW
QBYTE   EQU  .24        ;QUANTIDADE DE BYTES A SER RECEBIDO (22 ADRESS+ 2 DADO E DESPREZA OS 4 ANTICODE)
TGR     EQU  .255       ;TEMPO DE BOTÃO APERTADO PARA APAGAR GRAVAÇAO

;=========================================================================================================
;                               RESET
;=========================================================================================================
    ORG 0X00
    GOTO START
;=========================================================================================================
;                               INTERRUPÇÃO
;=========================================================================================================

    ORG 0X04
    GOTO INT_MUDANÇA_TMR0
;=========================================================================================================
;                               INICIO DO PROGRAMA
;=========================================================================================================

START:

	BANK1
    CALL    0X3FF
    MOVWF   OSCCAL          ;CALIBRA OSCILADOR (CERTIFIQUE DE TER BYTE DE CALIBRAÇÃO SALVO)
	MOVLW	B'111110'		; SETUP PORTA
	MOVWF   TRISIO
	MOVLW	B'00000000'       ;TIMER0 /2
    MOVWF   OPTION_REG	
    IFDEF PIC_675
 	MOVLW .0
 	MOVWF ANSEL  ;LIBERA PORTAS DO AD (SOMENTE 12f675)
    ENDIF
    MOVLW   B'000010'
    MOVWF   WPU           ;LIGA PULLUP EM GP1
	BANK0
	MOVLW   0X07
	MOVWF	CMCON			;DESLIGA COMPARADORES
	CLRF	GPIO			; RESET PORT
    MOVLW   .0
    MOVWF   TMR0
    MOVFW 	GPIO         ;LER PARA ZERAR FLAG
    BCF   	INTCON,T0IF
    BSF   	INTCON,T0IE
    CLRF   FLAGS   ;APAGA REGISTRADOR DE FLAGS

     MOVLW  TGR
     MOVWF  Z2
     CLRF   Z1      ;LIMPA REGISTRADORES
     MOVLW  0X7F
     CALL   EEREAD
     ADDLW  .0
	 BCF     INTCON,GIE
     BTFSC  STATUS,Z
     BSF    INTCON,GIE
    
;=========================================================================================================
;                               ROTINA PRINCIPAL
;=========================================================================================================
INICIO:
    
     CLRF  RES3
     CLRF  RES2
     CLRF  RES1
	 CLRF  RES0
     MOVLW  QBYTE  ;PREPARA PARA A RECEPÇÃO COM NUMERO DE BITS A RECEBER
	 MOVWF  BITCOUNTER
     
L0
     BCF   FLAG   ;LIMPA FLAG E REGISTRADORES DE RECEPÇÃO
     CLRF  HC
     CLRF  LC
L1


     BTFSS  LRN   ;TESTA BOTÃO 'LEARN' APERTADO
     GOTO   TAPAGAMENTO  ;APERTADO, COMEÇA A CONTAR TEMPO MAX. DE APAGAMENTO
	 MOVLW  TGR
     MOVWF  Z2		;RECARGA DO TEMPO DE APAGAMENTO
     CLRF   Z1      ;LIMPA REGISTRADORES
L1H    
     GOTO    SS5
;=========================================================================================================
;                               ROTINA PARA APAGAMENTO GERAL DOS CONTROLES
;=========================================================================================================

TAPAGAMENTO       ;APAGAR TODOS OS CONTROLES DA MEMÓRIA
     DECFSZ Z1,F
     GOTO   L1H  
     DECFSZ Z2,F
     GOTO   L1H
     CALL   APAGAEEPROM ;ATINGIU TEMPO MAXIMO: APAGAR MEMÓRIA
     MOVLW  .3         ;PISCA 3 VEZES
     MOVWF  AUX2
     BSF    LED        ;ACENDE LED (UMA PISCADA)
     MOVLW  .10
     CALL   DELAYM
     BCF    LED        ;APAGA LED
     MOVLW  .10
     CALL   DELAYM
     DECFSZ AUX2,F
     GOTO   $-7
     BTFSS  LRN       ;AGUARDA SOLTAR BOTÃO 'LEARN'
     GOTO   $-1
     GOTO INICIO
;=========================================================================================================
;                               ROTINA DE RECEPÇÃO DE SINAIS HT6P20B
;=========================================================================================================

SS5:
;A  
	 
     BTFSS FLAG        ;TESTA FLAG DE HUM/ZERO RECEBIDO
	 GOTO  L2      ;FLAG=0
;B
     BTFSS SIN      ;SIN ? TESTA SINAL DE ENTRADA DO RECEPTOR DE RF
	 GOTO  M0       ; SIN=0

L2
;C
	 BTFSS SIN      ;SIN ?
     GOTO  LA1      ;SIN=0

;E
	 BSF   FLAG     ;SIN=1
     INCF  HC,F
     BTFSC STATUS,Z
     DECF  HC,F
     GOTO  LA2	   ;VAI CONTAR TEMPO DE 50 MICRO SEGUNDOS

LA1
;D
    INCF  LC,F     ;INCREMENTA REGISTRADOR DE LOW SIGNAL NA ENTRADA RF
    BTFSC STATUS,Z
    DECF  LC,F
LA2
   
J0

	MOVLW  .9  ;.9 = 50 MICROSEG    (ACERTA TEMPO ENTRE LEITURAS DA ENTRADA DE RF)
    MOVWF  CONT
    DECFSZ CONT,F
    GOTO $-1
    GOTO L1
M0

;F
    MOVFW  LC		    ;TESTA SE NÃO PASSOU DO LIMITE MAXIMO DE TEMPO EM LOW NA ENTRADA DE RF
    SUBLW  TMAX
    BTFSS  STATUS,C
    GOTO   INICIO       ;C=0 (-)  -  LC>TMAX (REJEITAR DADO - PAUSA INICIAL)
;F'
 
    
;G
    MOVFW  HC			;OBTEM O VALOR DE 'CARRY'(HUM OU ZERO)
    SUBWF  LC,W
    

    RRF    RES2,F		;DESLOCA  O BIT NOS REGISTRADORES DE RESULTADO
    RRF    RES1,F
    RRF    RES0,F

;H
	
    DECFSZ  BITCOUNTER,F  ;DECREMENTA O CONTADOR DE BITS A SER RECEBIDO
    GOTO   L0             ;LE PROXIMO BIT
    BTFSC  FLAG1        ;TESTA SE É A PRIMEIRA OU A SEGUNDA RECEPÇÃO
	GOTO   PULA1
    MOVFW  RES2         ;SALVA A PRIMEIRA LEITURA PARA COMPARAÇÃO COM UMA SEGUNDA
    MOVWF  RES2A
    MOVFW  RES1
    MOVWF  RES1A    
    MOVFW  RES0
    MOVWF  RES0A	
    BSF   FLAG1			;SETA FLAG DE PRIMEIRA RECEPÇÃO

    GOTO  INICIO
PULA1
	BCF FLAG1          ;SEGUNDA RECEPÇÃO, COMPARA COM A PRIMEIRA
	MOVFW  RES2
    XORWF  RES2A,W
    BTFSS  STATUS,Z
    GOTO   RESETAC
    MOVFW  RES1
    XORWF  RES1A,W
    BTFSS  STATUS,Z
    GOTO   RESETAC
	MOVFW  RES0
    XORWF  RES0A,W
    BTFSS  STATUS,Z
    GOTO   RESETAC	  ;ERRO DE RECEPÇÁO

    MOVFW  RES2
    MOVWF  RES3       ;SALVA RES2 EM RES3
    MOVLW  B'00111111'
    ANDWF  RES2,F     ;APAGA BOTÕES

	MOVFW  RES2      ;ELIMINA CODIGO 0X000000
    XORLW  .0
    BTFSC  STATUS,Z
    GOTO   RESETAC	  ;ERRO DE RECEPÇÁO
	MOVFW  RES1
    XORLW  .0
    BTFSC  STATUS,Z
    GOTO   RESETAC	  ;ERRO DE RECEPÇÁO
	MOVFW  RES0
 	XORLW  .0
    BTFSC  STATUS,Z
    GOTO   RESETAC	  ;ERRO DE RECEPÇÁO

    GOTO   AÇÃO       ;OK - BOA RECEPÇÃO

RESETAC
	CLRF   RES3A     ; APAGA RESULTADOS DE COMPARAÇÃO
    CLRF   RES2A
    CLRF   RES1A
	CLRF   RES0A
    GOTO INICIO


AÇÃO
;I
    BTFSS  LRN     ;BOTÃO ESTÁ APERTADO?
    BSF    FLAGGR
    CALL   PPT
    SUBLW  .0
    BTFSC  STATUS,Z  ; É '0'?
    GOTO   APRENDER    ;NENHUM CONTROLE FOI  GRAVADO
MADDRESS
    MOVFW  TMP
	MOVWF  ADDRESS
    CALL   EEREAD
    XORWF  RES2,W      ;COMPARA COM RES2
    BTFSS  STATUS,Z
    GOTO   PROXIMO
    DECF   ADDRESS,F
    MOVFW  ADDRESS
    CALL   EEREAD
    XORWF  RES1,W      ;COMPARA COM RES1
    BTFSS  STATUS,Z
    GOTO   PROXIMO
	DECF   ADDRESS,F
	MOVFW  ADDRESS
    CALL   EEREAD
    XORWF  RES0,W      ;COMPARA COM RES0
    BTFSC  STATUS,Z
    GOTO ACIONAR	   ;ENCONTRADO CONTROLE NA MEMÓRIA
PROXIMO					;VAI PARA O PROXIMO ENDEREÇO DE MEMÓRIA PROCURAR....
    
    MOVFW   ADDRESS
    MOVWF   TMP
    MOVLW   .3
    SUBWF   TMP,F	  ;ACERTA  DE 3 EM 3 A POSIÇÃO DE BUSCA NA MEMÓRIA

	BTFSS  STATUS,C  
	GOTO   APRENDER 

    BTFSS   STATUS,Z
    GOTO   MADDRESS   ;VOLTA A BUSCA
;=========================================================================================================
;                              APRENDER CONTROLES NOVOS
;=========================================================================================================   
    
APRENDER
    BTFSS  FLAGGR    ;TESTA SE BOTÃO 'LEARN' ESTÁ PRESSIONADO
    GOTO   INICIO    ;NÃO ESTÁ.
    CALL   PPT       ;ESTÁ, PEGA PONTEIRO
    MOVWF  ADDRESS   ;PEGA O ENDEREÇO APONTADO
	SUBLW  0X7E      ;LIMITE MAXIMO DA EEPROM (128-1 /3= 42 BOTÕES OU 24 CONTROLES)
    BTFSS  STATUS,C
    CLRF   ADDRESS    ;INICIA SOBREGRAVAÇÃO
    INCF   ADDRESS,F        ;SOMA 1
    MOVFW  RES0
    MOVWF  TMP		 ;COLOCA EM 'TMP'
    MOVFW  ADDRESS   ;DA O POSIÇÃO DE MEMORIA A SER GRAVADO
    CALL   EEWRITE   ;ROTINA DE ESCRITA NA EEPROM
    INCF   ADDRESS,F ;PROXIMA POSIÇÃO DE ESCRITA NA EEPROM
    MOVFW  RES1
    MOVWF  TMP
    MOVFW  ADDRESS 
    CALL   EEWRITE
    INCF   ADDRESS,F
    MOVFW  RES2
    MOVWF  TMP
    MOVFW  ADDRESS 
    CALL   EEWRITE
    MOVFW  ADDRESS
    MOVWF  TMP
    MOVLW  .0
    CALL   EEWRITE  ;GRAVA NOVO ENDEREÇO DE PONTEIRO
    BCF    FLAGGR
    BTFSS  LRN
    GOTO   $-1
    MOVLW  .10    ;TEMPO DE ATRASO
    CALL   DELAYM
    
    BSF   LED       ;LIGA LED
    MOVLW  .10    ;TEMPO DE ATRASO
    CALL   DELAYM
    BCF   LED       ;DESLIGA
;=========================================================================================================
;                               ACIONAR TRIAC MODO ON/OFF
;=========================================================================================================    
ACIONAR 
    MOVFW  RES3  ;RECUPERA OS BOTÕES
    MOVWF  RES2 

    BTFSC  RES2,7   ; TESTA BIT 7
    GOTO   LIGAR
	BTFSC  RES2,6  ;TESTA BIT 6
    GOTO   DESLIGAR
    GOTO INICIO

;=================================================================================================
;               LIGAR SAÍDA
;=================================================================================================
LIGAR

    BCF    FLAG_JAOFF		;DESLIGA FLAG JAOFF
    BTFSC   FLAG_JAON
	GOTO    LG_INT
    CLRF    TMP
    MOVLW   0X7F
    CALL    EEWRITE
    BSF     FLAG_JAON    
LG_INT
    BSF    INTCON,GIE
	GOTO  SAI_REG
;=================================================================================================
;               DESLIGAR SAÍDA
;=================================================================================================
DESLIGAR
    BCF    INTCON,GIE
    BTFSC  INTCON,GIE
    GOTO   $-2
    BCF    FLAG_JAON		;DESLIGA FLAG JAON
    BTFSC  FLAG_JAOFF
    GOTO   SAI_REG
    MOVLW   .1
    MOVWF   TMP
    MOVLW   0X7F			;GRAVA ESTADO NA EEPROM
    CALL    EEWRITE
    BSF    FLAG_JAOFF



SAI_REG
    GOTO    INICIO


;=========================================================================================================
;                               PONTEIRO PARA EEPROM
;=========================================================================================================

PPT
    MOVLW .0
    CALL  EEREAD    ;LE  PONTEIRO DA EEPROM
    RETURN
;=========================================================================================================
;                               ROTINAS DE DELAY
;=========================================================================================================
DELAYM     ; DELAY= 50 milisegundos X 'W'
   MOVWF  R0
XC
   CALL  AGUARDE
   DECFSZ R0,F
   GOTO XC
   RETURN

AGUARDE		; ROTINA DE ATRASO ENTRE OPERAÇÕES DE EEPROM (50 MSEG)
	MOVLW  .50
	MOVWF	R2
    CALL DELAY_1MS  ;ROTINA DE 1 MILISEGUNDOS
    DECFSZ  R2,F
    GOTO  $-2
    RETURN
DELAY_1MS
	MOVLW	.199
	MOVWF	R1
    CLRWDT
    NOP
	DECFSZ	R1,F
	GOTO $-3
	RETURN

;=========================================================================================================
;                              ESCREVER NA EEPROM INTERNA
;=========================================================================================================
EEWRITE
;endereço esta em ADDRESS
;DADOS A ESCREVER ESTA EM TMP(MSB)  

    BCF   INTCON,GIE
	BANK1
	movwf EEADR	
	BANK0
	MOVFW  TMP		;PEGA PRIMEIRO DADO
	BANK1
	movwf EEDATA
	bcf EECON1, EEIF	
	bsf EECON1, WREN ; enable Write\par
	movlw 0x55	
	movwf EECON2	
	movlw 0xAA	
	movwf EECON2	
	bsf EECON1, WR	
WRITE_SN_A clrwdt	
	btfsc EECON1, WR ; Write complete ?\par
	goto WRITE_SN_A	
	bcf EECON1, WREN ; disable Write\par
 	BANK0

	clrwdt	
	
ESPERA1			;DELAY ENTRE APAGAMENTOS
    BSF   INTCON,GIE
	RETURN
;=========================================================================================================
;                              LER A EEPROM INTERNA
;=========================================================================================================

EEREAD
;endereço esta em ADDRESS
;DADOS LIDOS SERÃO ESCRITOS EM TMP0
        
	clrwdt	
;	MOVFW  ADDRESS
	
	BANK1
	movwf EEADR	
	bsf EECON1, RD ; do a read\par
	clrwdt
    btfsc EECON1, RD ; Read done ?\par
	goto $-1	
	movf EEDATA,W
	BANK0
	MOVWF	TMP	;RECUPERA PRIMEIRO NUMERO DA EEPROM
	clrwdt	

	RETURN
;=========================================================================================================
;                ROTINA DE APAGAMENTO TOTAL DA EEPROM INTERNA
;=========================================================================================================
;------------------------------------------------------------------------------
APAGAEEPROM 
    BCF   INTCON,GIE  ;DESLIGA INTERRUPÇÕES
	MOVLW 0X80		;TOTAL DE 128 + 1 BYTES DE EEPROM
	MOVWF	AUX
RET6
	CLRWDT
	MOVFW	AUX
	MOVLW   .1  ;ACERTA ENDEREÇO TIRANDO 1
	SUBWF	AUX,W
	BANK1
	movwf EEADR	
	MOVLW	0XFF
	movwf EEDATA
	bcf EECON1, EEIF	
	bsf EECON1, WREN ; enable Write\par
	movlw 0x55	
	movwf EECON2	
	movlw 0xAA	
	movwf EECON2	
	bsf EECON1, WR	
WRITE_SN_C clrwdt	
	btfsc EECON1, WR ; Write complete ?\par
	goto WRITE_SN_C	
	bcf EECON1, WREN ; disable Write\par
 	BANK0
	DECFSZ	AUX,F
	GOTO  ESPERA
	clrwdt	
    BSF  INTCON,GIE  ;RELIGA INTERRUPÇÕES
	RETLW 0H
ESPERA			;DELAY ENTRE APAGAMENTOS
	MOVLW  .8
	MOVWF	R1
CG1
	MOVLW	.255
	MOVWF	R2
	
	DECFSZ	R2,F
	GOTO $-1
	DECFSZ	R1,F
	GOTO CG1
	GOTO RET6


;=============================================================================
;               INTERRUPÇOES DO TIMER0 E MUDANÇA DE ESTADO DO PINO SENSOR
;=============================================================================
; A CADA 512 MICROSEGUNDOS, DISPARA  O TRIAC, SE INTERRUPÇÃO ESTIVER HABILITADA.
INT_MUDANÇA_TMR0
	MOVWF    WTEMP       		;SALVA 'W'
    SWAPF    STATUS,W    		;SALVA 'STATUS'
    MOVWF    STATUSTEMP
    BANK0
    BCF      INTCON,T0IF        ;APAGA FLAG DO TMR0
;=================================================================================================
;               DISPARA TRIAC QUANDO INTERRUPÇÃO ESTIVER HABILITADA
;=================================================================================================
    BCF     GATE
    BANK1
    BCF     TRISGATE            ;SAIDA ATERRADA
    BANK0    
    MOVLW   .250               ;TEMPO DO DISPARO NA GATE 
    ADDLW   .1
    BTFSS   STATUS,Z
    GOTO    $-2
    BANK1
    BSF    TRISGATE            ;ALTA IMPEDANCIA
    BANK0    
    BCF    INTCON,T0IF			;FLAG TIMER0
;=============================================================================
;               ENCERRA ROTINA DE INTERRUPÇÃO
;=============================================================================
SAI_INT
     
    SWAPF  STATUSTEMP,W   		;RECUPERA 'STATUS'
    MOVWF  STATUS
    SWAPF  WTEMP,F
    SWAPF  WTEMP,W        		;RECUPERA 'W'
	RETFIE
;=========================================================================================================
;                               PRÉ-ESCRITA NA EEPROM
;=========================================================================================================
   ORG H'2100' 
   DE  .0
   ORG H'2100'+0X7F
   DE  .1
     end