;****************************************************************************************
;    RX_GEN_3RX1TX.ASM
;
;    
;    RECEPTOR RF PARA CONTROLE REMOTOS (CHAVEIRINHOS) COM CI HT6P20B
; 
;    PARA DECODIFICAR UTILIZA UM PIC 12F675 (OPCIONALMENTE UM 12F629, DES-
;    COMENTANDO/COMENTANDO  AS LINHAS CITADAS NO TEXTO).
;
;    CLAUDIO LÁRIOS        INICIO: 06-05-2013  TERMINO:06-05-2013
;    OBJETIVO: CONSTRUINDO 3 RECEPTORES IGUAIS E APENAS COLOCANDO JUMPERS
;    PODEREMOS COM UM UNICO TRANSMISSOR DE 3 BOTÕES, CONTROLAR 3 APLICAÇÕES
;    SEPARADAS EM MODO RETENÇÃO OU PULSO, CONFIGURANDO POR JUMPER.
;    O BOTÃO QUE ACIONARÁ SERÁ TAMBÉM ESCOLHIDO POR POSIÇÃO DE JUMPER.
;***************************************************************************************
;
;   GRAVAR CONTROLE:  APERTE O BOTÃO DO CONTROLE REMOTO QUE VOCÊ DESEJA QUE SEJE O  QUE 
;   ACIONARÁ ESTE RECEPTOR E MANTENHA APERTADO.
;   APERTE TAMBÉM O BOTÃO 'LEARN' NA PLACA QUE DESEJA 'APRENDER'(PINO 7 DO PIC 12F675 
;   A MASSA)E  SOLTE-O EM MENOS DE 1 SEGUNDOS.  O LED 'LEARN'   PISCARÁ 1 VEZ, PARA INDICAR 
;   'CODE APRENDIDO'. 
;   APAGAR TODOS OS CONTROLES DA MEMÓRIA:  APERTAR BOTÃO 'LEARN' NA PLACA E 
;   MANTENHA PRESSIONADO POR MAIS DE 10 SEGUNDOS.    O LED 'LEARN'  PISCARÁ
;   3 VEZES , INDICANDO O PLENO APAGAMENTO DE TODOS OS CONTROLES DA MEMÓRIA.
;   APÓS ISTO, CADA CONTROLE DEVERÁ SER 'REAPRENDIDO' NOVAMENTE PARA OPERAR.
;************************************************************************************** 
;     DESCOMENTAR/COMENTAR CONFORME MODELO ESCOLHIDO
#DEFINE F675
;#DEFINE F629
;**************************************************************************************


    IFDEF  F675
	INCLUDE "P12F675.INC"
	LIST P=12f675 , R=DEC
    ENDIF

    IFDEF  F629
 	LIST P=12f629 , R=DEC
 	INCLUDE "P12F629.INC"
    ENDIF

;--------------------------
	ERRORLEVEL      -302   
	__CONFIG		_CP_OFF & _PWRTE_ON & _WDT_OFF & _INTRC_OSC_NOCLKOUT & _BODEN_ON & _MCLRE_OFF


#DEFINE		BANK0	 BCF	STATUS,RP0 	 ;SETA BANK0 DE MEMORIA
#DEFINE		BANK1	 BSF	STATUS,RP0	 ;SETA BANK1

#DEFINE		FLAG	 FLAGS,0          ;FLAG DE SITUAÇÃO
#DEFINE		FLAG1	 FLAGS,1     	 ;FLAG DE NOVA LEITURA
#DEFINE		FLAGGR 	 FLAGS,2     	 ;FLAG DE 'LEARN' APRENDER
#DEFINE     FLAG_BAP FLAGS,3         ;FLAG DE 'BOTÃO AINDA APERTADO'
#DEFINE TRIS_LEARN   TRISIO,0         ;IN /OUT 'LEARN'


#DEFINE SIN 		 GPIO,3           ;PINO 4  IN RF
#DEFINE LRN  		 GPIO,0           ;PINO 7  IN LEARN BOTTON
#DEFINE LED  		 GPIO,0           ;PINO 7  SAIDA LED 'LEARN'

#DEFINE RELE      	 GPIO,1	         ;PINO 6- SAIDA DO RELE
#DEFINE P_R      	 GPIO,2	         ;PINO 5- JUMPER PARA PULSO/RETENÇÃO
#DEFINE B_E      	 GPIO,5	         ;PINO 2- JUMPER PARA BOTÃO ESQUERDO
#DEFINE B_D      	 GPIO,4	         ;PINO 3- JUMPER PARA BOTÃO DIREITO


     CBLOCK  0X20
 RES3,RES2,RES1,RES0,AUX,C3,C2,C1,C0,WS,TEMP,BITCOUNTER,FLAGS,TL0,TL1,TL2,Z2,Z1,Y1,Y2
  LcdDelayCounter,LcdDelayCounter1,tmpLcdRegister,tmpLcdRegister1,SITUAÇÃO
  temp,SDATA,AUX2 ,LC,HC ,CONT,RES3A,RES2A,RES1A,RES0A,X,R0,R1,R2,TMP1,TMP2,TMP3,ADDRESS,TMP
     ENDC


YTRIS	EQU	B'111101'	; PORTA: TRI-STATE VALUE  
TMAX    EQU  .50       ;TEMPO MAXIMO DO SINAL LOW
QBYTE   EQU  .28        ;QUANTIDADE DE BYTES A SER RECEBIDO (22 ADRESS+ 2 DADO+ 4 ANTICODE)
TGR     EQU  .255       ;TEMPO DE BOTÃO APERTADO PARA APAGAR GRAVAÇAO

T_DESL_LED EQU .10     ;TEMPO MÁXIMO QUE LEDS FICAM ACESOS APÓS CESSAR TRANSMISSÃO

    ORG 0X00
    GOTO START
    ORG 0X04
    RETFIE

START:
	 MOVLW   0X07
	 MOVWF	CMCON			;DESLIGA COMPARADORES
	 CLRF	GPIO			; RESET PORT
     BANK1
     CLRF   OPTION_REG
     MOVLW  0XFF
     MOVWF  WPU             ;LIGA PULL UPS
	 MOVLW	YTRIS			; SETUP PORTA
     MOVWF   TRISIO

     IFDEF F675
     CLRF    ANSEL  ;LIBERA PORTAS DO AD (somente 12f675)
     ENDIF
     BANK0
	 CLRF   FLAGS   ;APAGA REGISTRADOR DE FLAGS
     MOVLW  TGR
     MOVWF  Z2
     CLRF   Z1      ;LIMPA REGISTRADORES
INICIO:
    
     CLRF  RES3
     CLRF  RES2
     CLRF  RES1
	 CLRF  RES0
     MOVLW  QBYTE  ;PREPARA PARA A RECEPÇÃO COM NUMERO DE BITS A RECEBER
	 MOVWF  BITCOUNTER
     
L0
     BCF   FLAG   ;LIMPA FLAG E REGISTRADORES DE RECEPÇÃO
     CLRF  HC
     CLRF  LC
L1
;---------------------------------

     BTFSS  LRN   ;TESTA BOTÃO 'LEARN' APERTADO
     GOTO   TAPAGAMENTO  ;APERTADO, COMEÇA A CONTAR TEMPO MAX. DE APAGAMENTO
	 MOVLW  TGR
     MOVWF  Z2		;RECARGA DO TEMPO DE APAGAMENTO
     CLRF   Z1      ;LIMPA REGISTRADORES
L1H    
     GOTO    SS5

TAPAGAMENTO       ;APAGAR TODOS OS CONTROLES DA MEMÓRIA
     DECFSZ Z1,F
     GOTO   L1H  
     DECFSZ Z2,F
     GOTO   L1H
     CALL   APAGAEEPROM ;ATINGIU TEMPO MAXIMO: APAGAR MEMÓRIA
    
     BANK1 
     BCF    TRIS_LEARN  ;SAIDA PARA LED LEARN
     BANK0
     BSF    LED        ;ACENDE LED (UMA PISCADA)
     MOVLW  .10
     CALL   DELAYM
     BCF    LED        ;APAGA LED
     MOVLW  .10
     CALL   DELAYM
 	 BSF    LED        ;ACENDE LED (UMA PISCADA)
     MOVLW  .10
     CALL   DELAYM
     BCF    LED		   ;APAGA LED
     MOVLW  .10
     CALL   DELAYM
     BSF    LED        ;ACENDE LED (UMA PISCADA)
     MOVLW  .10
     CALL   DELAYM
     BCF    LED	       ;APAGA LED
     MOVLW  .10
     CALL   DELAYM
   	 BANK1
     BSF    TRIS_LEARN  ;VIRA ENTRADA PARA BOTÃO 'LEARN'
     BANK0
     BTFSS  LRN       ;AGUARDA SOLTAR BOTÃO 'LEARN'
     GOTO   $-1
     GOTO INICIO

;===================ROTINA DE RECEPÇÃO==========================
SS5:
;A  
	 
     BTFSS FLAG        ;TESTA FLAG DE HUM/ZERO RECEBIDO
	 GOTO  L2      ;FLAG=0
;--------------------------------
;B
     BTFSS SIN      ;SIN ? TESTA SINAL DE ENTRADA DO RECEPTOR DE RF
	 GOTO  M0       ; SIN=0
;----------------------------------
L2
;C
	 BTFSS SIN      ;SIN ?
     GOTO  LA1      ;SIN=0
;-------------------------------------
;E
	 BSF   FLAG     ;SIN=1
     INCF  HC,F
     BTFSC STATUS,Z
     DECF  HC,F
     GOTO  LA2	   ;VAI CONTAR TEMPO DE 50 MICRO SEGUNDOS
;-------------------------------------------------------------------------------------
LA1
;D
    INCF  LC,F     ;INCREMENTA REGISTRADOR DE LOW SIGNAL NA ENTRADA RF
    BTFSC STATUS,Z
    DECF  LC,F
LA2
    
     DECFSZ Y1,F    ;CONTADOR DE TEMPO DE DESLIGAMENTO DE SAIDA
     GOTO   J0
     DECFSZ Y2,F    ;CONTADOR DE TEMPO DE DESLIGAMENTO DE SAIDA
     GOTO   J0
;===================================================================================
;BOTÃO DO TX FOI SOLTO (SEM TRANSMISSÃO)
;TESTA JUMPER EM P_R (SE MODO PULSO OU RETENÇÃO)
     BTFSC  P_R
     BCF   RELE     ;MODO PULSO- DESLIGA RELE
     BCF   FLAG_BAP ;MODO RETENÇÃO- PERMITE INVERSÃO 
     INCF  Y1,F
     INCF  Y2,F
J0

	MOVLW  .11  ;.11 = 50 MICROSEG    (ACERTA TEMPO ENTRE LEITURAS DA ENTRADA DE RF)
    MOVWF  CONT
    DECFSZ CONT,F
    GOTO $-1
    GOTO L1




M0
;----------------------------------
;F
    MOVFW  LC		    ;TESTA SE NÃO PASSOU DO LIMITE MAXIMO DE TEMPO EM LOW NA ENTRADA DE RF
    SUBLW  TMAX
    BTFSS  STATUS,C
    GOTO   INICIO       ;C=0 (-)  -  LC>TMAX (REJEITAR DADO - PAUSA INICIAL)
;F'
 
;-----------------------------------
    
;G
    MOVFW  HC			;OBTEM O VALOR DE 'CARRY'(HUM OU ZERO)
    SUBWF  LC,W
    
    RRF    RES3,F       ;DESLOCA  O BIT NOS REGISTRADORES DE RESULTADO
    RRF    RES2,F
    RRF    RES1,F
    RRF    RES0,F
;-------------------------------------
;H
	
    DECFSZ  BITCOUNTER,F  ;DECREMENTA O CONTADOR DE BITS A SER RECEBIDO
    GOTO   L0             ;LE PROXIMO BIT
    
    MOVLW  .4             ;DESPREZA OS BITS DE 'ANTICODE' 1010
    MOVWF  BITCOUNTER
ACERTA
    BCF    STATUS,C
    RRF    RES3,F
    RRF    RES2,F
    RRF    RES1,F
    RRF    RES0,F        ;RESULTADO FICA SOMENTE EM RES2 A RES0,DESPREZA RES3
	DECFSZ BITCOUNTER,F
    GOTO   ACERTA
	


    BTFSC  FLAG1        ;TESTA SE É A PRIMEIRA OU A SEGUNDA RECEPÇÃO
	GOTO   PULA1
    MOVFW  RES2         ;SALVA A PRIMEIRA LEITURA PARA COMPARAÇÃO COM UMA SEGUNDA
    MOVWF  RES2A
    MOVFW  RES1
    MOVWF  RES1A    
    MOVFW  RES0
    MOVWF  RES0A	
    BSF   FLAG1			;SETA FLAG DE PRIMEIRA RECEPÇÃO

    GOTO  INICIO
PULA1
	BCF FLAG1          ;SEGUNDA RECEPÇÃO, COMPARA COM A PRIMEIRA
	MOVFW  RES2
    XORWF  RES2A,W
    BTFSS  STATUS,Z
    GOTO   RESETAC
    MOVFW  RES1
    XORWF  RES1A,W
    BTFSS  STATUS,Z
    GOTO   RESETAC
	MOVFW  RES0
    XORWF  RES0A,W
    BTFSS  STATUS,Z
    GOTO   RESETAC	  ;ERRO DE RECEPÇÁO
    GOTO   AÇÃO       ;OK - BOA RECEPÇÃO

RESETAC
	CLRF   RES3A     ; APAGA RESULTADOS DE COMPARAÇÃO
    CLRF   RES2A
    CLRF   RES1A
	CLRF   RES0A
    GOTO INICIO




;-------------------------------------
AÇÃO
;I

    MOVFW  RES2
    MOVWF  RES3    ;SALVA BOTÕES
    ANDLW  0X3F    ;APAGA BOTÕES
    MOVWF  RES2    
    BTFSS  LRN     ;BOTÃO ESTÁ APERTADO?
    BSF    FLAGGR
    CALL   PPT
    SUBLW  .0
    BTFSC  STATUS,Z  ; É '0'?
    GOTO   APRENDER    ;NENHUM CONTROLE FOI  GRAVADO
MADDRESS
    MOVFW  TMP
	MOVWF  ADDRESS
    CALL   EEREAD
    XORWF  RES2,W      ;COMPARA COM RES2
    BTFSS  STATUS,Z
    GOTO   PROXIMO
    DECF   ADDRESS,F
    MOVFW  ADDRESS
    CALL   EEREAD
    XORWF  RES1,W      ;COMPARA COM RES1
    BTFSS  STATUS,Z
    GOTO   PROXIMO
	DECF   ADDRESS,F
	MOVFW  ADDRESS
    CALL   EEREAD
    XORWF  RES0,W      ;COMPARA COM RES0
    BTFSC  STATUS,Z
    GOTO ACIONAR	   ;ENCONTRADO CONTROLE NA MEMÓRIA
PROXIMO					;VAI PARA O PROXIMO ENDEREÇO DE MEMÓRIA PROCURAR....
    
    MOVFW   ADDRESS
    MOVWF   TMP
    MOVLW   .3
    SUBWF   TMP,F	  ;ACERTA  DE 3 EM 3 A POSIÇÃO DE BUSCA NA MEMÓRIA

	BTFSS  STATUS,C  
	GOTO   APRENDER 

    BTFSS   STATUS,Z
    GOTO   MADDRESS   ;VOLTA A BUSCA
   
    
APRENDER
    BTFSS  FLAGGR    ;TESTA SE BOTÃO 'LEARN' ESTÁ PRESSIONADO
    GOTO   INICIO    ;NÃO ESTÁ.
    CALL   PPT       ;ESTÁ, PEGA PONTEIRO
    MOVWF  ADDRESS   ;PEGA O ENDEREÇO APONTADO
	SUBLW  0X7E      ;LIMITE MAXIMO DA EEPROM (128-1 /3= 42 BOTÕES OU 24 CONTROLES)
    BTFSS  STATUS,C
    CLRF   ADDRESS    ;INICIA SOBREGRAVAÇÃO
    INCF   ADDRESS,F        ;SOMA 1
    MOVFW  RES0
    MOVWF  TMP		 ;COLOCA EM 'TMP'
    MOVFW  ADDRESS   ;DA O POSIÇÃO DE MEMORIA A SER GRAVADO
    CALL   EEWRITE   ;ROTINA DE ESCRITA NA EEPROM
    INCF   ADDRESS,F ;PROXIMA POSIÇÃO DE ESCRITA NA EEPROM
    MOVFW  RES1
    MOVWF  TMP
    MOVFW  ADDRESS 
    CALL   EEWRITE
    INCF   ADDRESS,F
    MOVFW  RES2
    MOVWF  TMP
    MOVFW  ADDRESS 
    CALL   EEWRITE
    MOVFW  ADDRESS
    MOVWF  TMP
    MOVLW  .0
    CALL   EEWRITE  ;GRAVA NOVO ENDEREÇO DE PONTEIRO
    BCF    FLAGGR
    BTFSS  LRN
    GOTO   $-1
    BANK1
    BCF    TRIS_LEARN  ;VIRA SAIDA
    BANK0
    BCF   LED       ;LIGA LED
    MOVLW  .10    ;TEMPO DE ATRASO
    CALL   DELAYM
    BSF   LED       ;DESLIGA
    MOVLW  .10    ;TEMPO DE ATRASO
    CALL   DELAYM
    BANK1
    BSF  TRIS_LEARN ;VIRA ENTRADA
    BANK0
    
ACIONAR   
;==================================================================
;TESTA POR 2 JUMPER COLOCADOS EM B_E / B_D
    BTFSC  B_E
    GOTO   ONLY_B_D  ;B_E SEM JUMPER (1)
    BTFSC  B_D
	GOTO   ONLY_B_E
;==============================
;  SOMENTE COM AMBOS BOTÕES ACIONADOS NO CONTROLE (OU TERCEIRO BOTÃO)
	BTFSS  RES3,7
	GOTO   REC_TEMPO
	BTFSC  RES3,6
	GOTO   LIGAR
    GOTO   REC_TEMPO
	
ONLY_B_E
;=================================
;JUMPER APENAS EM B_E
    BTFSC  RES3,7
    GOTO   ONLY_B_D
    BTFSC  RES3,6
    GOTO   LIGAR
	GOTO   REC_TEMPO

;==================================
;NENHUM JUMPER EM AMBOS (B_E /B_D_)
; OU SOMENTE COLOCADO EM B_D
ONLY_B_D
    BTFSC  B_D
    GOTO   REC_TEMPO
    BTFSC  RES3,6
    GOTO   REC_TEMPO
    BTFSC  RES3,7
    GOTO   LIGAR
	GOTO   REC_TEMPO

REC_TEMPO
    MOVLW  T_DESL_LED  ;RECARGA DO TEMPORIZADOR DE DESLIGAMENTO
    MOVWF  Y2
    CLRF  Y1
    GOTO INICIO
;=================================================================
;ACIONAR RELE DE SAIDA
LIGAR
    BTFSS  P_R
    GOTO   RETENÇÃO
;================================================================
;MODO PULSO
	BSF    RELE  ;LIGA RELE
    BCF    FLAG_BAP
    GOTO   REC_TEMPO
;================================================================
;MODO RETENÇÃO
RETENÇÃO
   BTFSC  FLAG_BAP
   GOTO   REC_TEMPO
   BTFSS  RELE
   GOTO   LIG_RELE
   BCF    RELE            ;DESLIGA RELE
PR_C
   BSF    FLAG_BAP
   GOTO   REC_TEMPO
LIG_RELE
   BSF    RELE            ;LIGA RELE
   GOTO   PR_C
;--------------------------------------------------------------
DELAYM
   MOVWF  R0
XC
   CALL  AGUARDE
   DECFSZ R0,F
   GOTO XC
   RETURN

;****************************************************
;PEGA PONTEIRO NA EEPROM - ULTIMO ENDEREÇO
PPT
    MOVLW .0
    CALL  EEREAD    ;LE  PONTEIRO DA EEPROM
    RETURN

AGUARDE		;ROTINA DE ATRASO ENTRE OPERAÇÕES DE EEPROM

	MOVLW  .64
	MOVWF	R1
CG2
	CLRWDT
	MOVLW	.255
	MOVWF	R2
	
	DECFSZ	R2,F
	GOTO $-1
	DECFSZ	R1,F
	GOTO CG2
	RETURN


EEWRITE

; ******* EEPROM WRITE ENABLE ******************
;endereço esta em ADDRESS
;DADOS A ESCREVER ESTA EM TMP(MSB)  


	BANK1
	movwf EEADR	
	BANK0
	MOVFW  TMP		;PEGA PRIMEIRO DADO
	BANK1
	movwf EEDATA
	bcf EECON1, EEIF	
	bsf EECON1, WREN ; enable Write\par
	movlw 0x55	
	movwf EECON2	
	movlw 0xAA	
	movwf EECON2	
	bsf EECON1, WR	
WRITE_SN_A clrwdt	
	btfsc EECON1, WR ; Write complete ?\par
	goto WRITE_SN_A	
	bcf EECON1, WREN ; disable Write\par
 	BANK0

	clrwdt	
	
ESPERA1			;DELAY ENTRE APAGAMENTOS
	CALL  AGUARDE
	RETURN



EEREAD
;endereço esta em ADDRESS
;DADOS LIDOS SERÃO ESCRITOS EM TMP0
        
	clrwdt	
;	MOVFW  ADDRESS
	
	BANK1
	movwf EEADR	
	bsf EECON1, RD ; do a read\par
	clrwdt
    btfsc EECON1, RD ; Read done ?\par
	goto $-1	
	movf EEDATA,W
	BANK0
	MOVWF	TMP	;RECUPERA PRIMEIRO NUMERO DA EEPROM
	clrwdt	

	RETURN
;------------------------------------------------------------------------------
APAGAEEPROM ;OK TESTADA E APROVADA
; ROTINA PARA APAGAR TODAS AS POSIÇOES DA EEPROM DO 16F628
	


	MOVLW 0X80		;TOTAL DE 128 + 1 BYTES DE EEPROM
	MOVWF	AUX
RET6
	CLRWDT
	MOVFW	AUX
	MOVLW   .1  ;ACERTA ENDEREÇO TIRANDO 1
	SUBWF	AUX,W
	BANK1
	movwf EEADR	
	MOVLW	0XFF
	movwf EEDATA
	bcf EECON1, EEIF	
	bsf EECON1, WREN ; enable Write\par
	movlw 0x55	
	movwf EECON2	
	movlw 0xAA	
	movwf EECON2	
	bsf EECON1, WR	
WRITE_SN_C clrwdt	
	btfsc EECON1, WR ; Write complete ?\par
	goto WRITE_SN_C	
	bcf EECON1, WREN ; disable Write\par
 	BANK0
	DECFSZ	AUX,F
	GOTO  ESPERA
	clrwdt	
	RETLW 0H
ESPERA			;DELAY ENTRE APAGAMENTOS
	MOVLW  .8
	MOVWF	R1
CG1
	MOVLW	.255
	MOVWF	R2
	
	DECFSZ	R2,F
	GOTO $-1
	DECFSZ	R1,F
	GOTO CG1
	GOTO RET6
    
   ORG H'2100' 
   DE  .0

     end