;*******************************************************************************************************************
;	PROJETO: PAINEL INDICADOR DE CHAMADAS PARA ATENDENTE C/ INDICAÇÃO POR LEDS
;   ATENDE 4 SALAS PARA UM PAINEL C/ 4 LEDS.
;   INICIO : 02/01/13 TERM.:  03/1/2013  
;   
;	AUTOR:  CLÁUDIO  LÁRIOS
;   BLOG 'LARIOS.TECNOLOGIA.WS'
;	PROCESSADOR:  PIC   12F629					
;	OBJETIVO: VISUALIÇÃO EM PAINEL DE LEDS, O NÚMERO DA SALA QUE PEDE SERVIÇOS DE MANUTENÇÃO/PRESENÇA DE PESSOA
;    O ACIONAMENTO DESTE PAINEL, SERÁ POR  4 CONTROLES REMOTOS (CHAVEIRINHOS) 
;   COMERCIAL (USADOS EM CONTROLE REMOTO DE PORTÕES,POR EX.)QUE USE CI HT6P20B.
;   CADA CONTROLE (CHAVEIRINHO) TEM QUE SER 'APRENDIDO' INICIALMENTE ANTES DO USO.
;   USO: 1) APRENDER CONTROLE:
;   APERTE QUALQUER BOTÃO DO CONTROLE REMOTO PRÓXIMO DO PAINEL, E EM SEGUIDA APERTE O BOTÃO
;   'LEARN' POR 1 SEGUNDO E SOLTE. O LED 'LEARN' PISCARÁ, INDICANDO APRENDIZADO E ACENDERÁ
;   O LED CORRESPONDENTE.
;       2) APERTAR BOTÃO 'LEARN' POR MAIS DE 10 SEGUNDOS APAGARÁ TODOS OS CONTROLES GRAVADOS.
;
;   OS CONTROLES APRENDIDOS CORRESPONDERÃO A SEQUENCIA EM QUE FOREM APRENDIDOS E CADA CONTROLE CORRESPONDENTE
;   FICARÁ COM UMA PESSOA EM CADA SALA.
;   AO APERTAR QUALQUER TECLA DO CONTROLE REMOTO (CHAVEIRINHO) ACENDERÁ O LED RESPECTIVO DA SALA QUE PEDE A PRESENÇA 
;   FUNCIONÁRIO;
;   SERÁ EMITIDO UM SINAL SONORO PARA CHAMAR ATENÇÃO A MUDANÇA NOS LEDS.
;   APÓS FEITO O ATENDIMENTO, DEVERÁ APERTAR O BOTÃO CORRESPONDENTE PARA APAGAR O LED.
;   ATENÇÃO: QUANDO SE TENTA PROGRAMAR MAIS DE 4 CONTROLES, OCORRERÁ SOBRE-ESCRITA E O NÃO FUNCIONAMENTO
;   DOS ANTERIORES CONTROLES GRAVADOS. APRENDA UM CONTROLE POR VEZ E NA QUANTIDADE DE 4 CONTROLES.

;   USO APENAS DIDÁTICO  (SUJEITO A BUGS)
;
;___________________________________________________________________________________________________


;   OSCILADOR INTERNO DE 4MHZ
#INCLUDE<P12F629.INC> ;    ARQUIVO PADRAO	
	__CONFIG	_BODEN_ON & _CP_OFF & _PWRTE_ON & _WDT_OFF  & _MCLRE_OFF  &  _INTRC_OSC_NOCLKOUT

   ERRORLEVEL      -302     			;SUPRESSÃO DE MENSAGEM DE ERRO

;=============================================================================
;PAGINACAO DE MEMORIA;
#DEFINE		BANK0	BCF	STATUS,RP0 	;SETA BANK0 DE MEMORIA
#DEFINE		BANK1	BSF	STATUS,RP0	;SETA BANK1

#DEFINE		FLAG	FLAGS,0          ;FLAG DE SITUAÇÃO
#DEFINE		FLAG1	FLAGS,1     	 ;FLAG DE NOVA LEITURA
#DEFINE		FLAGGR	FLAGS,2     	 ;FLAG DE 'LEARN' APRENDER
#DEFINE		FLAGTA	FLAGS,3          ;FLAG DE TEMPO MAXIMO DE APRESENTAÇÃO

#DEFINE		XFLAG_LED1	FLAGS1,4      ;XFLAG LED1
#DEFINE		XFLAG_LED2	FLAGS1,5      ;XFLAG LED2
#DEFINE		XFLAG_LED3	FLAGS1,6      ;XFLAG LED3
#DEFINE		XFLAG_LED4	FLAGS1,7      ;XFLAG LED4		


#DEFINE 	SIN 	    GPIO,3  ;PINO 4  IN RF
#DEFINE 	SOM         GPIO,5  ;PINO 2 SAIDA DE SOM
#DEFINE 	LRN  		GPIO,5	;PINO 2 IN LEARN BOTTON
#DEFINE 	LED  		GPIO,5  ;PINO 2 SAIDA LED 'LEARN'

#DEFINE 	LED1  		GPIO,4  ;PINO 3 SAIDA LED1 
#DEFINE 	LED2  		GPIO,2  ;PINO 5 SAIDA LED2 
#DEFINE 	LED3  		GPIO,1  ;PINO 6 SAIDA LED3 
#DEFINE 	LED4  		GPIO,0  ;PINO 7 SAIDA LED4 

#DEFINE 	TRIS_LED1  		TRISIO,4  ;PINO 3 SAIDA LED1 
#DEFINE 	TRIS_LED2  		TRISIO,2  ;PINO 5 SAIDA LED2 
#DEFINE 	TRIS_LED3  		TRISIO,1  ;PINO 6 SAIDA LED3 
#DEFINE 	TRIS_LED4  		TRISIO,0  ;PINO 7 SAIDA LED4 

;=================================================================================================
;RAM
     CBLOCK  0X20
 RES3,RES2,RES1,RES0,AUX,C3,C2,C1,C0,TEMP,BITCOUNTER,FLAGS,TL0,TL1,TL2,Z2,Z1
 AUX2 ,LC,HC ,CONT,RES3A,RES2A,RES1A,RES0A,X,R0,R1,R2,TMP1,TMP2,TMP3,ADDRESS,ADDRESS_S,TMP
  T3,T2,T1,RAU,AUX1,AUX4,AUX5,DEL5,FLAGS1
  TP1,TP0
     ENDC

;=================================================================================================
;EQUATES 
TMAX    EQU  .50           ;TEMPO MAXIMO DO SINAL LOW
QBYTE   EQU  .28           ;QUANTIDADE DE BYTES A SER RECEBIDO (22 ADRESS+ 2 DADO+ 4 ANTICODE)
TGR     EQU  .255          ;TEMPO DE BOTÃO APERTADO PARA APAGAR GRAVAÇAO
C_T3    EQU  .6
C_T2    EQU  .255
C_T1    EQU  .255



;=================================================================================================
;QUANTIDADE DE CONTROLES A SER USADO:
N_CONTROL EQU  4          ;NÚMERO MÁXIMO DE CONTROLES (APENAS 4 LEDS)
MAX_N_CONTROLES  EQU (N_CONTROL * 3) - 1 
;=================================================================================================
;RESET
    ORG 0X00
    GOTO START
;INTERRUPÇÕES
    ORG 0X04
    RETFIE

;====================================================
;SALTO GOTO 

MOSTRA
     MOVFW  C0
     SUBLW  .4
     BTFSS  STATUS,C   ;LIMITA DE 1 A 4
     RETURN
     BCF   STATUS,C
     RLF   C0,W   ;MULTIPLICA POR 2
     ADDWF   PCL,F
     NOP
     RETURN 
     BCF   LED1   ;LED1 ACENDE
     RETURN
     BCF   LED2   ;LED2 ACENDE
     RETURN
     BCF   LED3   ;LED3 ACENDE
     RETURN
     BCF   LED4   ;LED4 ACENDE
 	 RETURN
;================================================================================
;CONFIGURAÇÕES DE PORTAS E INICIALIZAÇÃO DE TEMPORIZADORES
START:
	MOVLW   0X07
	MOVWF	CMCON			;DESLIGA COMPARADORES
    MOVLW 0XFF              ;APAGAR LEDS
    
    BANK1
    MOVLW   B'00101000'   ;TUDO SAÍDA EXCETO RB3 COMO ENTRADA 'RFIN' E 'SW LEARN'
    MOVWF   TRISIO
    BANK0


	 CLRF   FLAGS   ;APAGA REGISTRADOR DE FLAGS
     CLRF   FLAGS1
    
     MOVLW  TGR
     MOVWF  Z2
     CLRF   Z1      ;LIMPA REGISTRADORES

	 
;==================================================================================
;INICIO DO LOOP PRINCIPAL
INICIO:
  
     CLRF  RES3
     CLRF  RES2
     CLRF  RES1
	 CLRF  RES0
     MOVLW  QBYTE  ;PREPARA PARA A RECEPÇÃO COM NUMERO DE BITS A RECEBER
	 MOVWF  BITCOUNTER
     
L0
     BCF   FLAG   ;LIMPA FLAG E REGISTRADORES DE RECEPÇÃO
     CLRF  HC
     CLRF  LC
L1

;=============================================
; TESTA CHAVES
	 BANK1
     BSF  TRIS_LED1   ;VIRA ENTRADAS
	 BSF  TRIS_LED2   
     BSF  TRIS_LED3   
	 BSF  TRIS_LED4   
     BANK0
     BSF    XFLAG_LED1
     BTFSS  LED1
     BCF    XFLAG_LED1
     BSF    XFLAG_LED2
     BTFSS  LED2
     BCF    XFLAG_LED2
     BSF    XFLAG_LED3
     BTFSS  LED3
     BCF    XFLAG_LED3
     BSF    XFLAG_LED4
     BTFSS  LED4
     BCF    XFLAG_LED4    

     BANK1
     BCF  TRIS_LED1   ;VIRA SAIDAS
	 BCF  TRIS_LED2   
     BCF  TRIS_LED3   
	 BCF  TRIS_LED4   
     BANK0

     BTFSS  XFLAG_LED1
     BSF    LED1          ;APAGA
     BTFSS  XFLAG_LED2
     BSF    LED2
     BTFSS  XFLAG_LED3
     BSF    LED3
     BTFSS  XFLAG_LED4
     BSF    LED4  

   
;========================================================================

    
     BTFSS  LRN   ;TESTA BOTÃO 'LEARN' APERTADO
     GOTO   TAPAGAMENTO  ;APERTADO, COMEÇA A CONTAR TEMPO MAX. DE APAGAMENTO
	 MOVLW  TGR
     MOVWF  Z2		;RECARGA DO TEMPO DE APAGAMENTO
     CLRF   Z1      ;LIMPA REGISTRADORES
L1H    
     GOTO    SS5

TAPAGAMENTO       ;APAGAR TODOS OS CONTROLES DA MEMÓRIA
     DECFSZ Z1,F
     GOTO   L1H  
     DECFSZ Z2,F
     GOTO   L1H
     CALL   APAGAEEPROM ;ATINGIU TEMPO MAXIMO: APAGAR MEMÓRIA
    
	BANK1
     BCF    TRISIO,5 ;VIRA SAIDA PARA O LED 'LEARN'
     BANK0
     BSF    LED        ;ACENDE LED (UMA PISCADA)
     MOVLW  .10
     CALL   DELAYM
     BCF    LED        ;APAGA LED
     MOVLW  .10
     CALL   DELAYM
 	 BSF    LED        ;ACENDE LED (UMA PISCADA)
     MOVLW  .10
     CALL   DELAYM
     BCF    LED		   ;APAGA LED
     MOVLW  .10
     CALL   DELAYM
     BSF    LED        ;ACENDE LED (UMA PISCADA)
     MOVLW  .10
     CALL   DELAYM
     BCF    LED	       ;APAGA LED
     MOVLW  .10
     CALL   DELAYM
     BANK1
     BSF    TRISIO,5 ;VIRA ENTRADA PARA TESTAR BOTÃO 'LEARN'
     BANK0
   	 
     BTFSS  LRN       ;AGUARDA SOLTAR BOTÃO 'LEARN'
     GOTO   $-1
     GOTO INICIO


SS5:
SEG88

;A  
	 
     BTFSS FLAG        ;TESTA FLAG DE HUM/ZERO RECEBIDO
	 GOTO  L2      ;FLAG=0
;--------------------------------
;B
     BTFSS SIN      ;SIN ? TESTA SINAL DE ENTRADA DO RECEPTOR DE RF
	 GOTO  M0       ; SIN=0
;----------------------------------
L2
;C
	 BTFSS SIN      ;SIN ?
     GOTO  LA1      ;SIN=0
;-------------------------------------
;E
	 BSF   FLAG     ;SIN=1
     INCF  HC,F
     BTFSC STATUS,Z
     DECF  HC,F
     GOTO  LA2	   ;VAI CONTAR TEMPO DE 50 MICRO SEGUNDOS
;---------------------------------------------------------
LA1
;D
    INCF  LC,F     ;INCREMENTA REGISTRADOR DE LOW SIGNAL NA ENTRADA RF
    BTFSC STATUS,Z
    DECF  LC,F
LA2
    
	MOVLW  .11  ;.11 = 50 MICROSEG    (ACERTA TEMPO ENTRE LEITURAS DA ENTRADA DE RF)
    MOVWF  CONT
    DECFSZ CONT,F
    GOTO $-1
    GOTO L1




M0
;----------------------------------
;F
    MOVFW  LC		    ;TESTA SE NÃO PASSOU DO LIMITE MAXIMO DE TEMPO EM LOW NA ENTRADA DE RF
    SUBLW  TMAX
    BTFSS  STATUS,C
    GOTO   INICIO       ;C=0 (-)  -  LC>TMAX (REJEITAR DADO - PAUSA INICIAL)
;F'
 
;-----------------------------------
    
;G
    MOVFW  HC			;OBTEM O VALOR DE 'CARRY'(HUM OU ZERO)
    SUBWF  LC,W
    
    RRF    RES3,F       ;DESLOCA  O BIT NOS REGISTRADORES DE RESULTADO
    RRF    RES2,F
    RRF    RES1,F
    RRF    RES0,F
;-------------------------------------
;H
	
    DECFSZ  BITCOUNTER,F  ;DECREMENTA O CONTADOR DE BITS A SER RECEBIDO
    GOTO   L0             ;LE PROXIMO BIT
    
    MOVLW  .4             ;DESPREZA OS BITS DE 'ANTICODE' 1010
    MOVWF  BITCOUNTER
ACERTA
    BCF    STATUS,C
    RRF    RES3,F
    RRF    RES2,F
    RRF    RES1,F
    RRF    RES0,F        ;RESULTADO FICA SOMENTE EM RES2 A RES0,DESPREZA RES3
	DECFSZ BITCOUNTER,F
    GOTO   ACERTA
	


    BTFSC  FLAG1        ;TESTA SE É A PRIMEIRA OU A SEGUNDA RECEPÇÃO
	GOTO   PULA1
    MOVFW  RES2         ;SALVA A PRIMEIRA LEITURA PARA COMPARAÇÃO COM UMA SEGUNDA
    MOVWF  RES2A
    MOVFW  RES1
    MOVWF  RES1A    
    MOVFW  RES0
    MOVWF  RES0A	
    BSF   FLAG1			;SETA FLAG DE PRIMEIRA RECEPÇÃO

    GOTO  INICIO
PULA1
	BCF FLAG1          ;SEGUNDA RECEPÇÃO, COMPARA COM A PRIMEIRA
	MOVFW  RES2
    XORWF  RES2A,W
    BTFSS  STATUS,Z
    GOTO   RESETAC
    MOVFW  RES1
    XORWF  RES1A,W
    BTFSS  STATUS,Z
    GOTO   RESETAC
	MOVFW  RES0
    XORWF  RES0A,W
    BTFSS  STATUS,Z
    GOTO   RESETAC	  ;ERRO DE RECEPÇÁO
    GOTO   AÇÃO       ;OK - BOA RECEPÇÃO

RESETAC
	CLRF   RES3A     ; APAGA RESULTADOS DE COMPARAÇÃO
    CLRF   RES2A
    CLRF   RES1A
	CLRF   RES0A
    GOTO INICIO




;-------------------------------------
AÇÃO
    MOVLW  0X0F
    ANDWF  RES2,F  ;APAGA BOTÕES
;I  
    BTFSS  LRN     ;BOTÃO ESTÁ APERTADO?
    BSF    FLAGGR
    CALL   PPT
    MOVWF  TMP1   ;SALVA
    SUBLW  .0
    BTFSC  STATUS,Z  ; É '0'?
    GOTO   APRENDER    ;NENHUM CONTROLE FOI  GRAVADO
MADDRESS
    MOVFW  TMP1
	MOVWF  ADDRESS
	CALL   EEREAD
    XORWF  RES2,W      ;COMPARA COM RES2
    BTFSS  STATUS,Z
    GOTO   PROXIMO
    DECF   ADDRESS,F
    MOVFW  ADDRESS
    CALL   EEREAD
    XORWF  RES1,W      ;COMPARA COM RES1
    BTFSS  STATUS,Z
    GOTO   PROXIMO
	DECF   ADDRESS,F
	MOVFW  ADDRESS
    CALL   EEREAD
    XORWF  RES0,W      ;COMPARA COM RES0
    BTFSC  STATUS,Z
    GOTO ACIONAR	   ;ENCONTRADO CONTROLE NA MEMÓRIA
PROXIMO					;VAI PARA O PROXIMO ENDEREÇO DE MEMÓRIA PROCURAR....
    
  
    MOVLW   .3
    SUBWF   TMP1,F	  ;ACERTA  DE 3 EM 3 A POSIÇÃO DE BUSCA NA MEMÓRIA
   	BTFSS  STATUS,C  
	GOTO   APRENDER 

    BTFSS   STATUS,Z
    GOTO   MADDRESS   ;VOLTA A BUSCA
   
    
APRENDER
    BTFSS  FLAGGR    ;TESTA SE BOTÃO 'LEARN' ESTÁ PRESSIONADO
    GOTO   INICIO    ;NÃO ESTÁ.
    CALL   PPT       ;ESTÁ, PEGA PONTEIRO
    MOVWF  ADDRESS   ;PEGA O ENDEREÇO APONTADO
	SUBLW  MAX_N_CONTROLES  ;LIMITE MAXIMO DA EEPROM (4 CONTROLES)
    BTFSS  STATUS,C
    CLRF   ADDRESS    ;INICIA SOBREGRAVAÇÃO
    INCF   ADDRESS,F        ;SOMA 1
    
    MOVFW  RES0
    MOVWF  TMP		 ;COLOCA EM 'TMP'
    MOVFW  ADDRESS   ;DA O POSIÇÃO DE MEMORIA A SER GRAVADO
    MOVWF  ADDRESS_S
    CALL   EEWRITE   ;ROTINA DE ESCRITA NA EEPROM
    INCF   ADDRESS,F ;PROXIMA POSIÇÃO DE ESCRITA NA EEPROM
    MOVFW  RES1
    MOVWF  TMP
    MOVFW  ADDRESS 
    CALL   EEWRITE
    INCF   ADDRESS,F
    MOVFW  RES2
    MOVWF  TMP
    MOVFW  ADDRESS 
    CALL   EEWRITE
    MOVFW  ADDRESS
    MOVWF  TMP
    MOVLW  .0
    CALL   EEWRITE  ;GRAVA NOVO ENDEREÇO DE PONTEIRO
    BCF    FLAGGR
   
    
    BANK1
    BCF   TRISIO,5   ;VIRA SAIDA
    BANK0
	BSF   LED       ;LIGA LED
    MOVLW  .10    ;TEMPO DE ATRASO
    CALL   DELAYM
    BCF   LED       ;LIGA LED
    MOVLW  .10    ;TEMPO DE ATRASO
    CALL   DELAYM
    BSF   LED       ;LIGA LED
    MOVLW  .10    ;TEMPO DE ATRASO
    CALL   DELAYM
     BANK1
    BSF   TRISIO,5   ;VIRA ENTRADA
    BANK0

	BTFSS  LRN
    GOTO   $-1
    MOVLW  .10       ;TEMPO DE ATRASO
    CALL   DELAYM
    MOVFW  ADDRESS_S ;RETORNA VALOR DE ADDRESS
    MOVWF  ADDRESS
ACIONAR   

  


;MOSTRA O NUMERO DA CAIXA (NÚMERO DO CONTROLE)
     MOVFW  ADDRESS   ;ESTA COM O NÚMERO DO CONTROLE
	 ADDLW .2
     MOVWF AUX
     CLRF C0
CFG
	 MOVLW 0X03
     SUBWF AUX,F
     BTFSC STATUS,Z
     GOTO  SGL
	 INCF  C0,F
     GOTO CFG

SGL
	 INCF  C0,F
     CALL MOSTRA
; GERA SOM PARA AVISAR DA MUDANÇA DO DISPLAY
     BCF   SOM
	 BANK1
     BCF    TRISIO,5 ;VIRA SAIDA PARA O SOM
     BANK0	
     CALL GERAR_SOM
     BANK1
     BSF    TRISIO,5 ;VIRA ENTRADA PARA TESTE DE BOTÃO 'LEARN'
     BANK0

;  CARREGA O TEMPO MÁXIMO DA APRESENTAÇÃO	
	BSF  FLAGTA
    MOVLW C_T3
    MOVWF T3
    MOVLW C_T2
    MOVWF T2
    MOVLW C_T1
    MOVWF T1    

    GOTO INICIO



;--------------------------------------------------------------
DELAYM
   MOVWF  R0
XC
   CALL  AGUARDE
   DECFSZ R0,F
   GOTO XC
   RETURN

;****************************************************
;PEGA PONTEIRO NA EEPROM - ULTIMO ENDEREÇO
PPT
    MOVLW .0
    CALL  EEREAD    ;LE  PONTEIRO DA EEPROM
    RETURN

AGUARDE		;ROTINA DE ATRASO ENTRE OPERAÇÕES DE EEPROM

	MOVLW  .64
	MOVWF	R1
CG2
	CLRWDT
	MOVLW	.255
	MOVWF	R2
	
	DECFSZ	R2,F
	GOTO $-1
	DECFSZ	R1,F
	GOTO CG2
	RETURN


EEWRITE

; ******* EEPROM WRITE ENABLE ******************
;endereço esta em ADDRESS
;DADOS A ESCREVER ESTA EM TMP(MSB)  


	BANK1
	movwf EEADR	
	BANK0
	MOVFW  TMP		;PEGA PRIMEIRO DADO
	BANK1
	movwf EEDATA
	bcf EECON1, EEIF	
	bsf EECON1, WREN ; enable Write\par
	movlw 0x55	
	movwf EECON2	
	movlw 0xAA	
	movwf EECON2	
	bsf EECON1, WR	
WRITE_SN_A clrwdt	
	btfsc EECON1, WR ; Write complete ?\par
	goto WRITE_SN_A	
	bcf EECON1, WREN ; disable Write\par
 	BANK0

	clrwdt	
	
ESPERA1			;DELAY ENTRE APAGAMENTOS
	CALL  AGUARDE
	RETURN

EEREAD
;endereço esta em ADDRESS
;DADOS LIDOS SERÃO ESCRITOS EM TMP0
        
	clrwdt	
	BANK1
	movwf EEADR	
	bsf EECON1, RD ; do a read\par
	clrwdt
    btfsc EECON1, RD ; Read done ?\par
	goto $-1	
	movf EEDATA,W
	BANK0
	MOVWF	TMP	;RECUPERA PRIMEIRO NUMERO DA EEPROM
	clrwdt	
	RETURN
;------------------------------------------------------------------------------
APAGAEEPROM ;OK TESTADA E APROVADA
; ROTINA PARA APAGAR TODAS AS POSIÇOES DA EEPROM DO 16F628
	MOVLW 0X80		;TOTAL DE 128 + 1 BYTES DE EEPROM
	MOVWF	AUX
RET6
	CLRWDT
	MOVFW	AUX
	MOVLW   .1  ;ACERTA ENDEREÇO TIRANDO 1
	SUBWF	AUX,W
	BANK1
	movwf EEADR	
	MOVLW	0XFF
	movwf EEDATA
	bcf EECON1, EEIF	
	bsf EECON1, WREN ; enable Write\par
	movlw 0x55	
	movwf EECON2	
	movlw 0xAA	
	movwf EECON2	
	bsf EECON1, WR	
WRITE_SN_C clrwdt	
	btfsc EECON1, WR ; Write complete ?\par
	goto WRITE_SN_C	
	bcf EECON1, WREN ; disable Write\par
 	BANK0
	DECFSZ	AUX,F
	GOTO  ESPERA
	clrwdt	
	RETLW 0H
ESPERA			;DELAY ENTRE APAGAMENTOS
	MOVLW  .8
	MOVWF	R1
CG1
	MOVLW	.255
	MOVWF	R2
	
	DECFSZ	R2,F
	GOTO $-1
	DECFSZ	R1,F
	GOTO CG1
	GOTO RET6





GERAR_SOM
;GERA SOM DE CAMPAINHA COM 3 NOTAS DIFERENTES  SEGUIDAS

			MOVLW  .63  ;FREQUENCIA DA 1ºNOTA
            MOVWF AUX1
           	MOVLW  0XFF ;DURAÇÃO
            MOVWF AUX4
            CALL G_FREQ

			MOVLW  .77 ;FREQUENCIA DA 2ºNOTA
            MOVWF AUX1
           	MOVLW  0XFF ;DURAÇÃO
            MOVWF AUX4
		    CALL G_FREQ

			MOVLW  .91 ;FREQUENCIA DA 3ºNOTA
            MOVWF AUX1
           	MOVLW  0XFF ;DURAÇÃO
            MOVWF AUX4
		    CALL G_FREQ
            RETURN

G_FREQ
            MOVFW AUX1
    		MOVWF AUX5
RECNOTA
	    	MOVFW AUX5
			MOVWF AUX1			
			BSF  SOM
C3F
			NOP
			NOP
			NOP
            NOP
            NOP
			DECFSZ AUX1,F
            GOTO C3F
			BCF  SOM
            MOVFW AUX5
            MOVWF AUX1
C3A
			NOP
			NOP
			NOP
            NOP
            NOP
			DECFSZ AUX1,F
            GOTO C3A
			DECFSZ AUX4,F
            GOTO RECNOTA
			RETURN


    
   ORG H'2100' 
   DE  .0

     end